Scalance Modul diagnose (s7-1500, TIA-portal)

FUNCTION_BLOCK "diagScalances"
{ S7_Optimized_Access := 'TRUE' }
VERSION : 0.1
   VAR 
      scalanceHwIds : Array[0..#maxScalNr] of UInt := [4(260)];
      scalanceErr : Array[0..#maxScalNr] of Bool;
      portLinkState : Array[1..8] of Byte;
      hwId : UInt;
      step3TON {InstructionName := 'TON_TIME'; LibVersion := '1.0'; S7_SetPoint := 'False'} : TON_TIME;
      exec : Bool;
      busy : Bool;
      done : Bool;
      error : Bool;
      status : Word;
      portInfo { S7_SetPoint := 'False'} : Array[1..8] of "LPNDR_typePortInformation";
      step { S7_SetPoint := 'True'} : Int;
      scalNr : Int;
      i : Int;
   END_VAR
 
   VAR CONSTANT 
      maxScalNr : Int := 3;
   END_VAR
 
 
BEGIN
	// Vamos, OB121
	// tested with TIA 16.0
 
	// NEED stetting:
	// maxScaleNr : number of scalances
	// scalanceHwIds : array of HWIDs (scalance HW ID interfaces from :
	// Devices & networks / Scalance / Properties / System constans / ~SCALANCE_interface_1 )
 
	// step0 : init (only one times after newstart)
	// step1 : set hw_id
	// step2 : exec set to 1
	// step3 : wait for answer
	// step4 : exec back to 0, error? write portLinkState array
	// step5 : next scalance nr -> step1
 
	// time functions
	// 
	#step3TON(IN:=(#step = 3),  // wait in step3, 2sec can modify
	          PT:=t#2s);
 
	IF #step = 0 THEN   // newstart, init
	    #scalNr := 0;   // start with first scalance
	    #step := 1;     // next step
	    #exec := false; // execute <- false
	    GOTO eof;
	END_IF;
 
	IF #step = 1 THEN // step1 : set hw_id
	    #hwId := #scalanceHwIds[#scalNr];  // hd id for scalance
	    #step := 2;
	    GOTO eof;
	END_IF;
 
	IF #step = 2 THEN   // step2 : exec set to 1
	    #exec := true; // execute <- true: start read process
	    #step := 3;
	    GOTO eof;
	END_IF;
 
	IF #step = 3 THEN        // step3 : wait for answer; wait 2sec (can modify)
	    IF #step3TON.Q THEN
	        #step := 4;
	    END_IF;
	    GOTO eof;
	END_IF;
 
	// portLinkState status:
	// 
	// 1 - Link is up
	// 2 - Link is down
	// 3 - port is in "testing" #status
	// 4 - Link #status is unknown
	// 5 - port is in "demand" mode
	// 6 - Link #status is NOT available
	// 7 - port #status is "LowerLayerDown"
 
	IF #step = 4 THEN  // step4 : exec back to 0, error? write portLinkState array
	    #exec := false; // execute <- false: stop read process
	    FOR #i := 1 TO 8 DO
	        #portLinkState[#i] := #portInfo[#i].portDiagnostic.portLinkState;
	    END_FOR;
	    #scalanceErr[#scalNr] := #done = false OR #error = true;
	    #step := 5;
	    GOTO eof;
	END_IF;
 
	IF #step = 5 THEN  // step5 : next scalance nr -> step1   
	    #step := 1;
	    #scalNr := #scalNr + 1;
	    IF #scalNr > #maxScalNr THEN
	        #scalNr := 0;
	    END_IF;
	    GOTO eof;
	END_IF;
 
	eof:
	;
 
	// 1: Interface information,
	// 2: MRP information,
	// 3: PORT information,
	// 4: PORT link status,
	// 5: PORT statistics
 
	// LPNDR software (and documentation) can download from:
	// https://support.industry.siemens.com/cs/document/109753067/bibliothek-f%C3%BCr-profinet-datens%C3%A4tze?dti=0&lc=de-WW
 
	"LPNDR_ReadGlobalInfo_DB"(execute:=#exec,
	                          hwId:=#hwId,
	                          mode:=3,
	                          busy=>#busy,
	                          done=>#done,
	                          error=>#error,
	                          status=>#status,
	                          DataRecord:=#portInfo);
 
 
 
 
END_FUNCTION_BLOCK